@echo off
REM 2013-09-09 CivFanatics user Puppeteer
REM I suspect a lot of Civ3 on Vista/Win7/Win8 problems are due to VirtualStore.
REM VirtalStore is difficult to explain, but perhaps it's easy to script?
REM The purpose of this file is to try to tell the user if they have Civ3
REM files in VirtualStore which may cause them issues.
REM Issues Include:
REM VirtualStore files may not go away after uninstall
REM Mod files in protected location and VirtualStore may be out of sync
REM Running Civ3 with different privileges (user, admin, compatibility) may cause different files to be used
REM First, does VirtualStore exist on this user profile?
set VS=%LOCALAPPDATA%\VirtualStore
if not exist %VS%\NUL goto NOVIRTUALSTORE
echo VirtualStore folder detected at %VS%
REM Civ3 is 32-bit program; if on 64-bit OS the registry entries are in a different place
REM Let's figure out if we're on a 64-bit OS or 32-bit OS
REM Yoinked from http://stackoverflow.com/questions/4990839/batch-to-detect-if-system-is-a-32-bit-or-64-bit
REM In theory need to test for "if not defined %PROCESSOR_ARCHITEW6432%" but I can't figure out how to "and" an if statement and have the else without goto's
echo.
echo Detecting if we are running 32-bit, otherwise assume 64-bit:
set WOW6432=""
if %PROCESSOR_ARCHITECTURE%==x86 (
rem 32 bit
echo 32-bit
) else (
rem 64 bit
echo 64-bit
set WOW6432=Wow6432Node\
)
REM Let's get the installed paths from the registry
REM Yoinked reg-query-to-variable method from http://stackoverflow.com/questions/10359001/how-to-read-a-reg-value-into-an-environment-variable
echo.
echo Reading install paths from registry...
for /f "tokens=2*" %%x in ('reg query "HKLM\Software\%WOW6432%Infogrames Interactive\Civilization III" /v Install_Path') do set CIV3=%%y
for /f "tokens=2*" %%x in ('reg query "HKLM\Software\%WOW6432%Infogrames\Civ3PTW" /v Install_Path') do set PTW=%%y
for /f "tokens=2*" %%x in ('reg query "HKLM\Software\%WOW6432%Infogrames\Conquests" /v Install_Path') do set C3C=%%y
REM Now let's assume VirtualStore paths
REM I don't know how VirtualStore works if %LOCALAPPDATA% and the installed path are different drive letters, but it's probably and edge case
REM The ~pn in the %%~pnx takes just the path and "file" name (in this case the folder) and omits the drive letter. I can't to this directly with an environment variable, so I'm using the "for" construct so I can use it on %%x
for %%x in ("%CIV3%") do set VSCIV3=%VS%%%~pnx
for %%x in ("%PTW%") do set VSPTW=%VS%%%~pnx
for %%x in ("%C3C%") do set VSC3C=%VS%%%~pnx
echo.
echo Your CivIII install location:
echo %CIV3%
if exist %VSCIV3%\NUL (
echo There are VirtualStore files that may override this location at:
echo %VSCIV3%
) else (
echo There is no VirtualStore detected for this folder.
)
echo.
echo Your PTW install location:
echo %PTW%
if exist %VSPTW%\NUL (
echo There are VirtualStore files that may override this location at:
echo %VSPTW%
) else (
echo There is no VirtualStore detected for this folder.
)
echo.
echo Your Conquests install location:
echo %C3C%
if exist %VSC3C%\NUL (
echo There are VirtualStore files that may override this location at:
echo %VSC3C%
) else (
echo There is no VirtualStore detected for this folder.
)
goto END
:NOVIRTUALSTORE
echo.
echo VirtualStore folder not detected on your user profile
echo at %VS%
echo Exiting
goto END
:END
REM debug:
REM echo.
REM echo %VS%
REM echo %CIV3%
REM echo %PTW%
REM echo %C3C%
REM echo %VSCIV3%
REM echo %VSPTW%
REM echo %VSC3C%
echo.
pause
